Arduino W5100 web server

Partie électronique

Le composant

Le Shiled Ethernet embarque un contrôleur Wiznet 5100 qui est plus fiable que son homologue le contrôleur ENC28J60. Il existe principalement en shield mais peut également se trouver en platine.

Wiznet 5100 version shield pour Mega/Uno	Wiznet 5100 version shield pour Nano	Wiznet 5100 version platine

Les versions shield sont intéressantes car elles embarquent également un lecteur de carte micro SD qui, dans notre cas de figure, va nous servir à héberger les pages du site Web.

Le montage

Le montage suivant requiert le shield, un câble Ethernet qui le relie à un switch et un ordinateur relié au même switch.

Shield Wiznet 5100 sur un Mega	Shield Wiznet 5100 sur un Uno	Shield Wiznet 5100 sur un Nano

N'oubliez pas que la communication entre l'Arduino et le shield se fait a travers certaines broches qu'il ne faut donc pas utiliser !

Comme vous pouvez le constater, le protocole SPI (Serial Port Interface) est utilisé ici pour communiquer avec la carte SD et le contrôleur Ethernet (SPI = pas en simultané).

Partie logicielle

Les librairies

Les librairies utilisées sont déjà inclues de base et sont :

• SPI.h
• Ethernet.h
• SD.h

Ethernet : attribution d'une adresse IP

Adressage IP dynamique

Le plus simple, si votre réseau possède un serveur DHCP (normalement votre box est dotée de cette fonctionnalité...), est de demander la configuration OSI de niveau 3. Les seuls paramètres qui nous intéresserons vraiment sont l'adresse IP et le masque. La passerelle ne sera pas utile dans notre cas...

#include <SPI.h>
#include <Ethernet.h>
/**
   Adresse MAC du module, doit être unique sur le réseau !
   Ici 00:01:02:03:04:05
*/
byte mac[] = { 0x00, 0x01, 0x02, 0x03, 0x04, 0x05 };

void setup() {
  // Démarrage du port série
  Serial.begin(9600);
  Serial.println(F("Requesting ip..."));
  /**
     Démarrage du shield Ethernet sans spécifier d'adresse IP
     Cela oblige le contrôleur Ethernet à demander une configuration OSI 3
  */
  if (Ethernet.begin(mac) == 0) {
    // Si c'est un échec, pas la peine de pousuivre...
    Serial.println(F("DHCP failure !"));
    while (true);
  }
  // Affichage des informations obtenues
  Serial.print(F("IP : "));
  Serial.println(Ethernet.localIP());
  Serial.print(F("Mask : "));
  Serial.println(Ethernet.subnetMask());
  Serial.print(F("Gateway : "));
  Serial.println(Ethernet.gatewayIP());
  Serial.print(F("DNS : "));
  Serial.println(Ethernet.dnsServerIP());
}
void loop() {
}

Si vous avez une réponse de votre serveur DHCP, vous devriez obtenir, dans le terminal série, le résultat suivant:

Requesting ip...
IP : 192.168.1.26
Mask : 255.255.255.0
Gateway : 192.168.1.254
DNS : 192.168.1.254

Adressage IP statique

On peut très bien spécifier une configuration OSI de niveau 3 de manière statique. Deux avantages : pas d'adresse IP qui change et c'est plus rapide !

#include <SPI.h>
#include <Ethernet.h>
// Adresse IP
IPAddress ip = { 192, 168, 1, 26 };
// Masque de sous-réseau
IPAddress mask = { 255, 255, 255, 0 };
// Passerelle
IPAddress gateway = { 192, 168, 1, 254 };
// DNS
IPAddress server_dns = { 192, 168, 1, 254 };
/**
   Adresse MAC du module, doit être unique sur le réseau !
   Ici 00:01:02:03:04:05
*/
byte mac[] = { 0x00, 0x01, 0x02, 0x03, 0x04, 0x05 };

void setup() {
  // Démarrage du port série
  Serial.begin(9600);
  Serial.println(F("Setting ip..."));
  /**
    Démarrage du shield Ethernet en spécifiant la configuration OSI 3
  */
  Ethernet.begin(mac, ip, server_dns, gateway, mask);
  // Affichage des informations
  Serial.print(F("IP : "));
  Serial.println(Ethernet.localIP());
  Serial.print(F("Mask : "));
  Serial.println(Ethernet.subnetMask());
  Serial.print(F("Gateway : "));
  Serial.println(Ethernet.gatewayIP());
  Serial.print(F("DNS : "));
  Serial.println(Ethernet.dnsServerIP());
}
void loop() {
}

Le même résultat que précédement devrait s'afficher dans le terminal série.

Adressage au choix !

Le must, c'est de pouvoir choisir en fonction du réseau ou on va placer notre montage ! Le code ci-dessous utilise la compilation conditionnelle pour faire cohabiter les deux codes précédents. Le choix se fera en fonction de la variable DHCP positionner au tout début du sketch.

#include <SPI.h>
#include <Ethernet.h>
/**
   Variable permettant de choisir entre une assignation
   fixe ou dynamique du niveau 3 OSI
   '0' --> configuration statique
   '1' --> configuration dynamique
*/
#define DHCP 0
/**
   Adresse MAC du module, doit être unique sur le réseau !
   Ici 00:01:02:03:04:05
*/
byte mac[] = { 0x00, 0x01, 0x02, 0x03, 0x04, 0x05 };
#if DHCP == 0
// Adresse IP
IPAddress ip = { 192, 168, 1, 26 };
// Masque de sous-réseau
IPAddress mask = { 255, 255, 255, 0 };
// Passerelle
IPAddress gateway = { 192, 168, 1, 254 };
// DNS
IPAddress server_dns = { 192, 168, 1, 254 };
#endif

void setup() {
  // Démarrage du port série
  Serial.begin(9600);
  /**
     Démarrage du shield Ethernet sans spécifier d'adresse IP
     Cela oblige le contrôleur Ethernet à demander une configuration OSI 3
  */
#if DHCP == 0
  Serial.println(F("Setting ip..."));
  Ethernet.begin(mac, ip, server_dns, gateway, mask);
#else
  Serial.println(F("Requesting ip..."));
  if (Ethernet.begin(mac) == 0) {
    // Si c'est un échec, pas la peine de pousuivre...
    Serial.println(F("DHCP failure !"));
    while (true);
  }
#endif
  // Affichage des informations obtenues
  Serial.print(F("IP : "));
  Serial.println(Ethernet.localIP());
  Serial.print(F("Mask : "));
  Serial.println(Ethernet.subnetMask());
  Serial.print(F("Gateway : "));
  Serial.println(Ethernet.gatewayIP());
  Serial.print(F("DNS : "));
  Serial.println(Ethernet.dnsServerIP());
}
void loop() {
}

Lorsque vous avez plusieurs possibilités n'hésitez pas à user de la compilation conditionnelle car, la mémoire réduite de l'ATMega ne permet pas d'embarquer beaucoup de code...

Ethernet : utilisation d'un serveur

Il est possible de démarrer un serveur qui écoutera sur un port précis. Dans notre cas de figure, le serveur utilisera le port TCP 80. Dans un premier temps, nous allons récupérer la requête qui vient du client pour voir comment elle est formatée. Dans un deuxième temps, on verra comment on pourra traiter et formuler une réponse.

Récupération de la requête

// !!!! Idem sketch précédent !!!! //
// Serveur écoutant sur le port 80
EthernetServer server(80);
void setup() {
  // !!!! Idem sketch précédent !!!! //
  // Démarrage du serveur
  server.begin();
}
void loop() {
  // On écoute les connections entrantes
  EthernetClient client = server.available();
  // Si la connection est établie (SYN / SYN+ACK / ACK)...
  if (client) {
    Serial.println(F("---- new request ----"));
    // ...pendant que le client maintient la session TCP...
    while (client.connected()) {
      // ...et que la requête contient des caractères...
      if (client.available()) {
        // ...on récupére les caractères...
        char c = client.read();
        // ... et on les affiche sur le terminal série
        Serial.print(c);
      }
    }
    // Fin de la requête
    Serial.println(F(""));
    Serial.println(F("---- end request ----"));
  }
}

Lorsque l'on entre dans la barre de recherche du navigateur l'adresse IP du module Ethernet on a, après le timeout TCP, le résultat suivant :

---- new request ----
GET / HTTP/1.1
Host: 192.168.1.26
User-Agent: Mozilla/5.0 (Windows NT 6.1; Win64; x64; rv:50.0) Gecko/20100101 Firefox/50.0
Accept: text/html,application/xhtml+xml,application/xml;q=0.9,*/*;q=0.8
Accept-Language: fr,fr-FR;q=0.8,en-US;q=0.5,en;q=0.3
Accept-Encoding: gzip, deflate
Connection: keep-alive
Upgrade-Insecure-Requests: 1


---- end request ----

On constate que :

• la requête démarre par le verbe HTTP (ici GET) suivit de l'URL (ici /) et du protocole (ici HTTP/1.1) ;
• la requête contient toutes les entêtes envoyés par le navigateur ;
• la requête se termine par deux sauts de ligne.

Pour terminer proprement la requête HTTP, il suffit de mettre fin à la session TCP à réception des deux sauts de ligne.

Traitement de fin de requête

On va écrire un programme qui attend le saut de ligne (\n) à la fin d'une ligne vide.

// !!!! idem sketch précédent !!!! //
void loop() {
  // On écoute les connections entrantes
  EthernetClient client = server.available();
  // Si la connection est établie (SYN / SYN+ACK / ACK)...
  if (client) {
    // Nos deux compteurs
    uint8_t nbNewLine = 0, bytesOnLine = 0;
    while (client.connected()) {
      if (client.available()) {
        char c = client.read();
        if (c != '\r') {
          if (c == '\n') {
            // Fin de ligne
            if (bytesOnLine == 0) {
              // Ligne vide on incrémente le conteur
              nbNewLine++;
              if (nbNewLine == 1) {
                // Deuxième ligne vide = fin requête
                // Envoie du status HTTP, ici '200 OK'
                client.println("HTTP/1.1 200 OK");
                // Entête spécifiant le contenu du corps
                client.println("Content-Type: text/html");
                /**
                   On prévient le client qu'à la fin de
                   la requête, on coupe la session TCP
                */
                client.println("Connection: close");
                // Spération entre les entêtes HTTP et le corps du message
                client.println();
                // contenu HTML
                client.println("<!DOCTYPE HTML>");
                client.println("<html>");
                client.println("It Works !");
                client.println("</html>");
                // On donne le temps au navigateur de traiter le message
                delay(1);
                // Fermeture de la session TCP
                client.stop();
                break;
              }
            } else {
              // Ligne contenant des caractères, on remet le conteur à zéro
              bytesOnLine = 0;
            }
          } else {
            // On incrémente le conteur de caractères
            bytesOnLine++;
          }
        }
      }
    }
    // Fin de la requête
    Serial.println(F(""));
    Serial.println(F("---- end request ----"));
  }
}

A partir de maintenant, côté navigateur, la requête se termine proprement et on attend plus le timeout TCP. Il faudrait maintenant, digérer l'URL pour pouvoir répondre en fonction de la requête !